// CE1 / Green Pattern Automaton '08.03
// by Tsutomu HIGO  URL:http://www.asahi-net.or.jp/~nj2t-hg/

#version 3.6;
global_settings {
  assumed_gamma 2.2
  max_trace_level 5
  }

light_source {<-300, 1000, -380> color <1, 1, 1>}

camera {
  location <0, 0, -200>
  angle 50
  look_at <0, 0, 0>
  }

#declare R1 = seed(3);
#declare Nmax = 96;
#declare Cp = array[2*Nmax][2];
#declare Nx = 0; #while (Nx < 2*Nmax)
  #declare Cp[Nx][0] = int(6.9999999*rand(R1));
#declare Nx = Nx+1; #end

union {
  #declare Ny = 1; #while (Ny < 1.5*Nmax)
    #declare Nx = 0; #while (Nx < 2*Nmax)
      #declare Cp[Nx][1] =
        mod(Cp[mod(Nx-1+2*Nmax, 2*Nmax)][0]+Cp[Nx][0]+Cp[mod(Nx+1, 2*Nmax)][0],8);
      #switch (Cp[Nx][1])
        #case (0) #declare Cp[Nx][1] = 6; #break
        #case (1) #declare Cp[Nx][1] = 0; #break
        #case (2) #declare Cp[Nx][1] = 1; #break
        #case (3) #declare Cp[Nx][1] = 3; #break
        #case (4) #declare Cp[Nx][1] = 0; #break
        #case (5) #declare Cp[Nx][1] = 3; #break
        #case (6) #declare Cp[Nx][1] = 1; #break
        #case (7) #declare Cp[Nx][1] = 0; #break
      #end
      #if(Cp[Nx][1] > 0)  
        sphere {<Nx-Nmax, Ny-1.5*Nmax/2, 0>, 0.5
          pigment {color rgb <1-Cp[Nx][1]/6, 1-Cp[Nx][1]/6, Cp[Nx][1]/6>}
          finish {
            reflection 0
            phong 1
            brilliance 1
            ambient 1
            }
          }
      #end
    #declare Nx = Nx+1; #end
    #declare Nx = 0; #while (Nx < 2*Nmax)
      #declare Cp[Nx][0] = Cp[Nx][1];
    #declare Nx = Nx+1; #end
  #declare Ny = Ny+1; #end
  no_shadow
  }

background {color rgb <0, 0.7, 0>}