// TWIGS3D / Colored Twigs '07.11
// by Tsutomu HIGO  URL:http://www.asahi-net.or.jp/~nj2t-hg/

#version 3.6;
global_settings {
  max_trace_level 8
  assumed_gamma 2.2
  }

light_source {<5000, 10000, -3000> color <1, 1, 1>}

camera {
  location <0, 70, -40>
  angle 110
  look_at <3, 50, 0>
  }

#declare R1 = seed(3);

#macro Dla33 (Nmax, Rds)
  #declare Cp = array[Nmax][6]
  #declare Cp[0][0] = 0; // x of sphere's center
  #declare Cp[0][1] = 0; // z of sphere's center
  #declare Cp[0][2] = 0; // y of sphere's center
  #declare Cp[0][3] = 0; // Distanse of sphere's center
  #declare Cp[0][4] = 2*pi*rand(R1); // Longitude Angle of sphere's center (keido)
  #declare Cp[0][5] = 0; // Latitude Angle of sphere's center (ido)
  sphere {
    <Cp[0][0], Cp[0][2], Cp[0][1]> Rds
    pigment {color rgb <1, 1-0/Nmax*0.8, 0.2>}
    finish {
      reflection 0.3
      phong 2
      brilliance 1
      ambient 0.4
      }
    no_shadow
    }

  #declare Np = 1; #while (Np < Nmax)
    #declare Cp[Np][4] = 2*pi*rand(R1);
    #declare Cp[Np][5] = 0;
    #if (Np = 1) 
          #declare Cp[Np][3] = 2; //Templary size
          #declare Cp[Np][0] = Cp[Np][3]*cos(Cp[Np][5])*cos(Cp[Np][4]);
          #declare Cp[Np][1] = Cp[Np][3]*cos(Cp[Np][5])*sin(Cp[Np][4]);
          #declare Cp[Np][2] = Np/30;
          #declare Nsclose = 0;
    #else
      #declare Ns = Np-1; #while (Ns>0)
          #declare Cp[Np][3] = Cp[Ns][3];
          #declare Cp[Np][0] = Cp[Np][3]*cos(Cp[Np][5])*cos(Cp[Np][4]);
          #declare Cp[Np][1] = Cp[Np][3]*cos(Cp[Np][5])*sin(Cp[Np][4]);
          #declare Cp[Np][2] = Np/30;//Cp[Np][3]*sin(Cp[Np][5]);
          #declare Det = 0;
        #declare Ldis = sqrt(pow(Cp[Np][0]-Cp[Ns][0],2)+pow(Cp[Np][1]-Cp[Ns][1],2)+pow(Cp[Np][2]-Cp[Ns][2],2));
        #if (Ldis < 1)
          #declare Apn = asin(Ldis/2/Cp[Ns][3]);
          #declare Cp[Np][3] = Cp[Ns][3]*cos(2*Apn)+sqrt(4-pow(Ldis*cos(Apn),2)); // Real size
          #declare Cp[Np][0] = Cp[Np][3]*cos(Cp[Np][5])*cos(Cp[Np][4]);
          #declare Cp[Np][1] = Cp[Np][3]*cos(Cp[Np][5])*sin(Cp[Np][4]);
          #declare Cp[Np][2] = Np/30;//Cp[Np][3]*sin(Cp[Np][5]);
          #declare Nsclose = Ns;
          #declare Det = 1;
          #declare Ns = 1;
        #end
      #declare Ns = Ns-1; #end
        #if (Det = 0)
          #declare Cp[Np][3] = 2;
          #declare Cp[Np][0] = Cp[Np][3]*cos(Cp[Np][5])*cos(Cp[Np][4]);
          #declare Cp[Np][1] = Cp[Np][3]*cos(Cp[Np][5])*sin(Cp[Np][4]);
          #declare Cp[Np][2] = Np/30;//Cp[Np][3]*sin(Cp[Np][5]);
          #declare Nsclose = 0;
        #end
    #end
    union {
      sphere {<Cp[Np][0], Cp[Np][2], Cp[Np][1]> Rds}
      cylinder {<Cp[Np][0], Cp[Np][2], Cp[Np][1]> <Cp[Nsclose][0], Cp[Nsclose][2], Cp[Nsclose][1]> Rds}
      pigment {color rgb <1, 1-Np/Nmax*0.8, 0.2>}
      finish {
        reflection 0.3
        phong 0
        brilliance 1
        ambient 0.4
        }
      rotate y*60
      no_shadow
      }
  #declare Np = Np+1; #end

#end

Dla33 (2400, 0.6)

intersection {
  plane {z, 30}
  plane {z, 30 rotate y*120}
  plane {z, 30 rotate y*-120}
  plane {y, 85}
  plane {-y, 5}
    pigment {color rgbt <1, 1, 1, 1>}
    finish {
      reflection 1
      phong 2
      brilliance 1
      ambient 0.1
      }
  }

background {color rgb <0.01, 0, 0.2>}