// CLUSTERS / Clusters 3 '07.01
// by Tsutomu HIGO  URL:http://www.asahi-net.or.jp/~nj2t-hg/

#version 3.6;
global_settings {
  max_trace_level 5
  assumed_gamma 2.2
  }

camera {
  location <70, -100, -260>
  look_at <-30, 100, 0>
  angle 70
  }

light_source {<0, -100, 1000> color rgb <0.24, 0.12, 0.1>}

union {
  #declare Kmax=15;
  #declare K=Kmax;
  #while (K>-Kmax)
    #declare Jmax=15;
    #declare J=Jmax;
    #while (J>-Jmax)
      #declare Imax=5;
      #declare I=Imax;
      #while (I>-Imax)
        disc {
          < 50*J-25+pow(-1,K)*12.5, 18*I/Imax, 25*pow(3,0.5)*K>
          y, 18*sqrt(1-pow(I/Imax,2)), 18*sqrt(1-pow(I/Imax,2))-5
          translate y*0.7*(K*K+J*J)
          }
      #declare I=I-1; #end
    #declare J=J-1; #end
  #declare K=K-1; #end
  texture {
    pigment {color rgbt <1, 1, 1, 0.9999>}
    finish {
      ambient 0.3
      diffuse 1
      reflection 1
      specular 0.8
      phong 0.5
      brilliance 1
      }
    }
  no_shadow
  }

background {color rgb <0.08, 0.1, 0.12>}