// CLUSTERS / Clusters 1 '07.01
// by Tsutomu HIGO  URL:http://www.asahi-net.or.jp/~nj2t-hg/

#version 3.6;
global_settings {
  max_trace_level 5
  assumed_gamma 2.2
  }

camera {
  location <-20, 200, -180>
  look_at <160, -300, 200>
  angle 70
  }

light_source { <430, 800, 1000> color rgb <0.4, 0.2, 0.1> }

union {
  #declare Kmax=20;
  #declare K=Kmax;
  #while (K>-6)
    #declare Jmax=20;
    #declare J=Jmax;
    #while (J>-3)
      #declare Imax=200;
      #declare I=Imax;
      #while (I>0)
        disc {
          < 50*J-25+pow(-1,K)*12.5, 0, 25*pow(3,0.5)*K>
          y, 25*(1-pow(0.7,I)), 20*(1-pow(0.7,I))
          translate y*-2*I-0.4*(K*K+J*J)
          }
      #declare I=I-1; #end
    #declare J=J-1; #end
  #declare K=K-1; #end
  texture {
    pigment {color rgbt <1, 1, 1, 0.99>}
    finish {
      ambient 0.3
      diffuse 0.5
      reflection 1
      specular 0.3
      phong 0.2
      brilliance 0.5
      }
    }
  no_shadow
  }

background {color rgb <0.05, 0.15, 0.2>}