// Graphic Gallery CYBERBUST / POLARS No.3 '06.07 improved version
// adviced by Friedrich Lohmueller http://www.f-lohmueller.de/index.htm
// by Tsutomu HIGO  URL: http://www.asahi-net.or.jp/~nj2t-hg/

#version 3.6;
global_settings {
  max_trace_level 6
  assumed_gamma 2.2
  }

camera {
  location <5, 10, -15>
  angle 84
  look_at <0, -6, 0.5>
  }

light_source { <300, 100, -100> color rgb <1, 0.6, 0.6> }

merge{
  isosurface {
    function { pow(cos(atan(z/x))-x,2)+pow(sin(atan(z/x))-z,2)
      +pow(y,2)- 0.1*(1+0.3*cos(6*atan(z/x))) }
    open
    contained_by { box { <0.000001, -1, -3> < 3, 1, 3> } }
    accuracy 0.01
    max_gradient 50
    }
  isosurface {
    function { pow(cos(atan(z/x))-x,2)+pow(sin(atan(z/x))-z,2)
      +pow(y,2)- 0.1*(1+0.3*cos(6*atan(z/x))) }
    open
    contained_by { box { <0.000001, -1, -3> < 3, 1, 3> } }
    accuracy 0.01
    max_gradient 50
    rotate y*180
    }
  scale 10
  texture { pigment { color rgbt <0.8, 0.8, 1, 0.7> } }
  finish {
    ambient 0.5
    diffuse 0.3
    reflection 0.8
    specular 0.8
    phong 0.5
    brilliance 1
    }
  no_shadow
  rotate y*30
  }

background { color rgb <0.001, 0.01, 0.05> }