// FEELER / 70-01 '06.02
// by Tsutomu HIGO  URL:http://www.asahi-net.or.jp/~nj2t-hg/

#version 3.6;
global_settings {
  max_trace_level 5
  assumed_gamma 2.2
  }

camera {
  location <-30, -120, -170>
  angle 90
  look_at <5, 30, 0.5>
  }

#declare Media = media {
  emission 0.05
  intervals 40
  samples 1, 50
  confidence 0.9999
  variance 1/100
  density {
    spherical
    turbulence 1.2
    color_map {
      [0.0 color rgbt <0, 0, 0, 1>]
      [0.1 color rgbt <1, 0.7, 0.5, 0.9>]
      [1 color rgb <1, 1, 1>]
      } 
    scale 25
    }
  }

union {
#declare I = 0; #declare Imax = 6; #while (I<Imax)
  union {
    intersection {
      sphere { 0, 30 scale <1, 1.5, 1> }
      sphere { 0, 29.9 scale <1, 1.5, 1> inverse }
      texture {
        pigment { color rgbf <1, 0.9, 0.9, 0.9> }
        finish {
          ambient 0.2
          diffuse 1
          reflection 0.5
          specular 0.8
          phong 0.5
          brilliance 1
          }
        }
      }
  #declare Cn =0; #while (Cn < 60)
    #declare R1 = seed(Cn*20);
    #declare Xr = 180*rand(0);
    #declare Yr = 360*rand(0);
    #declare Xp = 0;
    #declare Yp = 0;
    #declare Zp = 0;
    #declare Ctm = 100;
    #declare Ct = 0; #while (Ct < Ctm)
      #declare Xr = Xr+20*rand(R1)-10;
      #declare Yr = Yr+20*rand(R1)-10;
      #declare R = 0.4*(1-pow(Ct/Ctm,5));
      intersection {
        sphere { 0, 30 scale <1, 1.5, 1 > inverse }
        union {
          cylinder { <0, 0, 0>, <0, 1, 0>, R
            rotate <Xr, Yr, 0> translate <Xp, Yp, Zp> rotate x*90
            }
          sphere { <Xp, Yp, Zp> R rotate x*90 }
          pigment { color rgbt <1, 1, 1, 0.8> }
          finish {
            ambient 0.3
            diffuse 0.1
            reflection 0.8
            specular 1
            phong 0.5
            }
          no_shadow
          scale 2
          }
        }
      #declare Xp = Xp+sin(Xr*pi/180)*sin(Yr*pi/180);
      #declare Yp = Yp+cos(Xr*pi/180);
      #declare Zp = Zp+sin(Xr*pi/180)*cos(Yr*pi/180);
    #declare Ct = Ct+1; #end
  #declare Cn = Cn+1; #end
    sphere { 0, 29
      pigment { color rgbf <1, 1, 1, 1> }
      finish { ambient 0 diffuse 0 }
      interior { media { Media } }
      hollow
      rotate z*150
      scale <1, 1.5, 1>
      }
    translate x*120 rotate y*60*I
    no_shadow
    }
#declare I = I+1; #end
  pigment { rgbt <1, 0, 0, 0> }
  finish { ambient 0.3 reflection 1 diffuse 0.7 phong 1 }
  }

background { color rgb <0.3, 0.2, 0> }