// FEELER / 70-04 '06.02
// by Tsutomu HIGO  URL:http://www.asahi-net.or.jp/~nj2t-hg/

#version 3.6;
global_settings {
  max_trace_level 6
  assumed_gamma 2.2
  }

camera {
  location <0, -150, -180>
  angle 30
  look_at <-10, 5, 0>
  }

#declare Media1 = media {
  emission 0.01
  intervals 40
  samples 1, 50
  confidence 0.9999
  variance 1/100
  density {
    spherical
    turbulence 0.8
    color_map {
      [0.0 color rgbt <0, 0, 0, 1>]
      [0.5 color rgbt <1, 0, 0, 0.9>]
      [1 color rgb <1, 1, 1>]
      } 
    scale 60
    rotate <130, 220, 220>
    }
  }

union {
  union {
  #declare Cn = 0; #while (Cn < 240)
    union {
      #declare R1 = seed(Cn*20);
      #declare R0 = rand(R1);
      #declare Xr0 = 180*rand(0);
      #declare Xr = Xr0;
      #declare Yr0 = 360*rand(0);
      #declare Yr = Yr0;
      #declare Xp = 0;
      #declare Yp = 0;
      #declare Zp = 0;
      #declare Ctm = 50;
      #declare Rb = 2*(1+R0);
    #declare Ct = 0; #while (Ct < Ctm)
      #declare Xr = Xr+20*rand(R1)-10;
      #declare Yr = Yr+20*rand(R1)-10;
      #declare Rt = 2*(1+R0)/pow(2+Ct,0.8)*(1-pow((Ct+1)/Ctm,5));
      cone { <0, 0, 0>, Rb, <0, 1, 0>, Rt
        rotate x*Xr rotate y*Yr
        translate <Xp, Yp, Zp>
        }
      sphere { <0, 0, 0> Rb translate <Xp, Yp, Zp> }
      #declare Rb = Rt;
      #declare Xp = Xp+sin(Xr*pi/180)*sin(Yr*pi/180);
      #declare Yp = Yp+cos(Xr*pi/180);
      #declare Zp = Zp+sin(Xr*pi/180)*cos(Yr*pi/180);
    #declare Ct = Ct+1; #end
      rotate y*-Yr0 rotate x*-Xr0
      translate y*12
      rotate x*Xr0 rotate y*Yr0 rotate x*90
      }
  #declare Cn = Cn+1; #end
    pigment {color rgbt <1, 1, 1, 0.8>}
    finish {
      ambient 0.3
      diffuse 0.1
      reflection 0.8
      specular 1
      phong 0.5
      }
    no_shadow
    }
  sphere { 0, 100
    pigment { color rgbf <1, 1, 1, 1> }
    finish { ambient 0 diffuse 0 }
    interior { media { Media1 } }
    hollow
    rotate <120, 170, 250>
    }
  scale <1, 1.2, 1.3>
  rotate <140, 120, 170>
  }