// FEELER / 70-06 '06.02
// by Tsutomu HIGO  URL:http://www.asahi-net.or.jp/~nj2t-hg/

#version 3.6;
global_settings {
  max_trace_level 6
  assumed_gamma 2.2
  }

camera {
  location <-30, 120, -150>
  angle 96
  look_at <0, -110, 0>
  }

#declare Media1 = media {
  emission 0.08
  intervals 40
  samples 1, 50
  confidence 0.9999
  variance 1/100
  density {
    spherical
    turbulence 0.8
    color_map {
      [0 color rgb <0, 0, 0>]
      [0.3 color rgb <1, 0, 0>]
      [1 color rgb <1, 1, 1>]
      }
    scale 20
    }
  }

#declare Media2 = media {
  emission 0.08
  intervals 40
  samples 1, 50
  confidence 0.9999
  variance 1/100
  density {
    spherical
    turbulence 0.1
    color_map {
      [0.8 color rgb <0, 0, 0>]
      [0.85 color rgb <1, 0, 0>]
      [1 color rgb <1, 1, 1>]
      }
    scale 50
    }
  }

#declare I = 0; #declare Imax = 6; #while(I<Imax)
  union {
    intersection {
      sphere { 0, 20 }
      sphere { 0, 19.5 inverse}
      texture {
        pigment {color rgbf <1, 1, 1, 0.7> }
        finish {
          ambient 0.3
          diffuse 1
          reflection 1
          specular 0.8
          phong 0.5
          brilliance 1
          }
        }
      }
    sphere { 0, 19
      pigment { color rgbf <1, 1, 1, 1> }
      finish { ambient 0 diffuse 0 }
      interior { media { Media1 } }
      hollow
      rotate z*150
      }
  #declare Cn =0; #while (Cn < 30)
    union {
      #declare R1 = seed(Cn*10+I);
      #declare R0 = rand(R1);
      #declare Xr0 = 180*sin(pi*(0.5-0.4*rand(R1)));
      #declare Xr = Xr0;
      #declare Yr0 = 360*rand(R1);
      #declare Yr = Yr0;
      #declare Xp = 0;
      #declare Yp = 0;
      #declare Zp = 0;
      #declare Ctm = 50;
    #declare Ct = 0; #while (Ct < Ctm)
      #declare Xr = 0.1*180+0.9*Xr+40*rand(R1)-20;
      #declare Yr = Yr+10*rand(R1)-5;
      #declare R = 0.1*(3+R0)/pow(1+Ct,0.4)*(1-pow(Ct/Ctm,5));
      cylinder { <0, 0, 0>, <0, 1, 0>, R
        rotate x*Xr rotate y*Yr translate <Xp, Yp, Zp>
        }
      sphere { <0, 0, 0> R rotate x*Xr rotate y*Yr translate <Xp, Yp, Zp> }
      #declare Xp = Xp+sin(Xr*pi/180)*sin(Yr*pi/180);
      #declare Yp = Yp+cos(Xr*pi/180);
      #declare Zp = Zp+sin(Xr*pi/180)*cos(Yr*pi/180);
    #declare Ct = Ct+1; #end
      rotate y*-Yr0 rotate x*-Xr0
      scale 4*Xr0/180
      translate y*20
      rotate x*Xr0 rotate y*Yr0 rotate x*90
      }
  #declare Cn = Cn+1; #end
    pigment { color rgbt <1, 0.7, 0.7> }
    finish {
      ambient 0.5
      diffuse 0.3
      reflection 1
      specular 1
      phong 0.5
      }
    no_shadow
    scale <1+0.2*rand(R1), 1+0.2*rand(R1), 1+0.2*rand(R1)>
    rotate <15*rand(R1)-7.5, 15*rand(R1)-7.5, 15*rand(R1)-7.5>
    rotate y*90 translate x*150 rotate y*60*I
    }
#declare I = I+1; #end

sphere { 0, 30
  pigment { color rgbf <1, 1, 1, 1> }
  finish { ambient 0 diffuse 0 }
  interior { media { Media2 } }
  hollow
  rotate <270, 140, 120>
  scale 6
  }

background { color rgb <0, 0.01, 0.03> }