// FEELER / 70-03 '06.02
// by Tsutomu HIGO  URL:http://www.asahi-net.or.jp/~nj2t-hg/

#version 3.6;
global_settings {
  max_trace_level 7
  assumed_gamma 2.2
  }

camera {
  location <0, -150, -180>
  angle 30
  look_at <-1, -2, 0>
  }

#declare Media1 = media {
  emission 0.02
  intervals 40
  samples 1, 50
  confidence 0.9999
  variance 1/100
  density {
    spherical
    turbulence 1.2
    color_map {
      [0.0 color rgbt <0, 0, 0, 1>]
      [0.1 color rgbt <0.2, 0, 1, 0.9>]
      [1 color rgb <1, 1, 1>]
      }
    scale 20
    }
  }

union {
  union {
    intersection {
      sphere { 0, 20 }
      sphere { 0, 12 inverse}
      texture {
        pigment { color rgbf <1, 1, 1, 0.9> }
        finish {
          ambient 0.2
          diffuse 1
          reflection 1
          specular 0.8
          phong 0.5
          brilliance 1
          }
        }
      }
  #declare Cn = 0; #while (Cn < 240)
    union {
      #declare R1 = seed(Cn*20);
      #declare R0 = rand(R1);
      #declare Xr0 = 180*rand(0);
      #declare Xr = Xr0;
      #declare Yr0 = 360*rand(0);
      #declare Yr = Yr0;
      #declare Xp = 0;
      #declare Yp = 0;
      #declare Zp = 0;
      #declare Ctm = 50;
    #declare Ct = 0; #while (Ct < Ctm)
      #declare Xr = Xr+20*rand(R1)-10;
      #declare Yr = Yr+20*rand(R1)-10;
      #declare R = 2*(1+R0)/pow(1+Ct,1.2)*(1-pow(Ct/Ctm,5));
      cylinder { <0, 0, 0>, <0, 1, 0>, R
        rotate x*Xr rotate y*Yr
        translate <Xp, Yp, Zp>
        }
      sphere { <0, 0, 0> R translate <Xp, Yp, Zp> }
      #declare Xp = Xp+sin(Xr*pi/180)*sin(Yr*pi/180);
      #declare Yp = Yp+cos(Xr*pi/180);
      #declare Zp = Zp+sin(Xr*pi/180)*cos(Yr*pi/180);
    #declare Ct = Ct+1; #end
      rotate y*-Yr0 rotate x*-Xr0
      translate y*12
      rotate x*Xr0 rotate y*Yr0 rotate x*90
      }
  #declare Cn = Cn+1; #end
    pigment { color rgbt <0.6, 0.6, 0.6, 0.6> }
    finish {
      ambient 0.3
      diffuse 0.1
      reflection 1
      specular 1
      phong 0.5
      }
    no_shadow
    }
  sphere { 0, 18.8
    pigment { color rgbf <1, 1, 1, 1> }
    finish { ambient 0 diffuse 0 }
    interior { media { Media1 } }
    hollow
    rotate <120, 170, 250>
    }
  scale <1, 1.2, 1.3>
  rotate <140, 120, 170>
  }

background { color rgb <0.01, 0.1, 0.5> }