// PLANAR / Water '05.09
// By Tsutomu HIGO  URL: http://www.asahi-net.or.jp/~nj2t-hg/

#version 3.6;
global_settings {
  max_trace_level 6
  assumed_gamma 2.2
  }

#include "functions.inc"

camera {
  location <0, 800, 1000>
  look_at <0, -50, 0>
  angle 76
  }

union {
  isosurface { function { sqrt (x*x+y*y+z*z) -230 
    -f_agate (0.0002*(y+z), 0.0002*(x+z), 0.0002*(x+y)) *125 }
  contained_by { box {-2.5*350, 2.5*350} }
  accuracy 10
  max_gradient 100
    pigment { color rgbt <0.3, 0.5, 1, 0.7> }
    finish { ambient 0.1 reflection 1.2 phong 1 brilliance 1 diffuse 1 }
    rotate y*230 rotate x*23.45
    scale 2
    no_shadow
    }

  #declare Media = media {
    emission 0.05
    intervals 100
    samples 1, 100
    confidence 0.9999
    variance 1/1000
    density {
      planar
      ramp_wave
      turbulence 0.4
      color_map {
        [0.97  color rgb <0, 0, 0>]
        [0.98 color rgb <0.05, 0, 0>]
        [0.99 color rgb <0, 0.05, 0.1>]
        [1 color rgb <0.2, 0.2, 0.2>]
        }
      }
    }

  sphere { 0, 1
    pigment { color rgbf <1, 1, 1, 1> }
    finish { ambient 0 diffuse 0 }
    interior { media { Media } }
    scale 2000
    hollow
    }

  rotate z*-10 
  }