// PLANAR / Mushroom '05.09
// By Tsutomu HIGO  URL: http://www.asahi-net.or.jp/~nj2t-hg/

#version 3.6;
global_settings {
  max_trace_level 4
  assumed_gamma 2.2
  }

camera {
  location <2, 60, -65>
  look_at <0, 10, 0>
  angle 60
  }

light_source {<-20, 50, -25> color rgb <1, 1, 1>}

isosurface {
  function {pow(mod(x+30,3)-1.5,2)+pow(mod(z+30,3)-1.5,2)+pow(y/5,2)
    -0.01/(cos(y)*cos(y)+0.01)-0.04/(1-y)}
  threshold 0
  max_gradient 100
  contained_by {box {<-10, -1.89, -10>, <70, 0.9, 70>}}
  texture {
    pigment {color rgb <0.8, 0.7, 0.7>}
    finish {
      ambient 0.2
      diffuse 1
      reflection 0.3
      specular 0.8
      phong 0.5
      brilliance 1
      }
    }
  rotate z*180 rotate y*40 rotate x*27
  scale 6
  no_shadow
  }

#declare Media = media {
  emission 0.1
  intervals 50
  samples 1, 100
  confidence 0.7
  variance 1/1000
  density {
    planar
    ramp_wave
    turbulence 0.7
    color_map {
      [0 color rgb <0.12, 0.1, 0.1>]
      [0.3  color rgb <0, 0, 0>]
      [0.5  color rgb <0, 0, 0>]
      [0.9 color rgb <0, 0, 0.01>]
      [0.95 color rgb <0.06, 0.05, 0.3>]
      [1 color rgb <0.15, 0.15, 0.15>]
      }
    }
  }

sphere { 0, 2
  pigment { color rgbf <1, 1, 1, 1> }
  finish { ambient 0 diffuse 0 }
  interior { media { Media } }
  scale 100
  hollow
  rotate y*180 translate y*0 scale <1.5, 1, 1.5>
  }