// PLANAR / Hexagon '05.09
// By Tsutomu HIGO  URL: http://www.asahi-net.or.jp/~nj2t-hg/

#version 3.6;
global_settings {
  max_trace_level 4
  assumed_gamma 2.2
  }

camera {
  location <1, 20, -10>
  look_at <-5, 3, 0>
  angle 90
  }

light_source {<-20, 50, -25> color rgb <0.8, 0.7, 0.5>}

#declare fn_Pigm = function {
  pigment { hexagon
    color blue 1, color red 1, color green 1
    turbulence 0
    scale 0.2 rotate y*30
    }
  }

isosurface {
  function { (y-150*fn_Pigm(x, y, z).gray*0.6/(x*x+z*z+20))*(y+5)+4 }
  threshold 0
  max_gradient 500
  contained_by {box {<-5, -3, -10>, <10, 10, 10>}}
  texture {
    pigment {color rgb <1, 0.8, 0.6>}
    finish {
      ambient 0.0001
      diffuse 1
      reflection 0.5
      specular 1
      phong 0.5
      brilliance 1
      }
    }
  scale <150, 100, 150>
  translate <0, -280, 0>
  no_shadow
  }

#declare Media = media {
  emission 0.04
  intervals 50
  samples 1, 10
  confidence 0.9999
  variance 1/1000
  density {
    planar
    ramp_wave
    turbulence 0.6
    color_map {
      [0.89  color rgb <0, 0, 0>]
      [0.9 color rgb <0, 0.05, 0.3>]
      [1 color rgb <0.1, 0.1, 0.1>]
      }
    }
  }

sphere { 0, 2
  pigment { color rgbf <1, 1, 1, 1> }
  finish { ambient 0 diffuse 0 }
  interior { media { Media } }
  scale 500
  hollow
  rotate y*125 rotate z*20
  }