// PLANAR / Forest '05.09
// By Tsutomu HIGO  URL: http://www.asahi-net.or.jp/~nj2t-hg/

#version 3.6;
global_settings {
  max_trace_level 4
  assumed_gamma 2.2
  }

camera {
  location <1, 3, -20>
  look_at <-1, 5, 0>
  angle 100
  }

light_source {<-20, 50, -25> color rgb <1, 1, 0.3>}

isosurface {
  function {y-4*pow(sin(6*(x/2+0.5*cos(pi/3*y))-0.5*x*x)*sin(3*z), 10)}
  threshold 0
  max_gradient 40
  contained_by {box {<-pi*5, 0.001, -pi*5>, <pi*5, 4.001, pi*5>} }
  texture {
    pigment {color rgbt <1, 0.9, 0.7, 0.9>}
    finish {
      ambient 0.2
      diffuse 1
      reflection 0.5
      specular 0.8
      phong 0.5
      brilliance 1
      }
    }
  no_shadow
  scale 3
  rotate <15, 200 ,5>
  }

#declare Media = media {
  emission 0.1
  intervals 50
  samples 1, 10
  confidence 0.9999
  variance 1/1000
  density {
    planar
    ramp_wave
    turbulence 0.5
    color_map {
      [0.8  color rgb <0, 0, 0>]
      [0.9 color rgb <0, 0.05, 0.3>]
      [1 color rgb <0.1, 0.1, 0.1>]
      }
    }
  }

sphere { 0, 2
  pigment { color rgbf <1, 1, 1, 1> }
  finish { ambient 0 diffuse 0 }
  interior { media { Media } }
  scale 150
  hollow
  rotate y*160
  translate y*30
  }