// PLANAR / Birth '05.09
// By Tsutomu HIGO  URL: http://www.asahi-net.or.jp/~nj2t-hg/

#version 3.6;
global_settings {
  max_trace_level 4
  assumed_gamma 2.2
  }

#include "functions.inc"

camera {
  location <1, 300, -100>
  look_at <10, 20, 0>
  angle 120
  }

isosurface {
  function { sqrt (x*x+y*y+z*z) -10 -f_agate(0.01*x, 0.01*y, 0.01*z) *10 }
  threshold 0
  accuracy 1
  max_gradient 1000
  contained_by {box {<-30, -30, -300>, <30, 30, 30>}}
  texture {
    pigment {color rgbt <1, 0.4, 0.3, 0.4>}
    finish { ambient 0.4 reflection 1 phong 1 brilliance 1 diffuse 1 }
    }
  scale 6
  no_shadow
  }

#declare Media = media {
  emission 0.05
  intervals 50
  samples 1, 10
  confidence 0.9999
  variance 1/1000
  density {
    planar
    ramp_wave
    turbulence 0.6
    color_map {
      [0.98  color rgb <0, 0, 0>]
      [0.993 color rgb <0, 0.05, 0.1>]
      [0.995 color rgb <0.7, 0.1, 0>]
      [1 color rgb <0.5, 0.5, 0.5>]
      }
    }
  }

sphere { 0, 1
  pigment { color rgbf <1, 1, 1, 1> }
  finish { ambient 0 diffuse 0 }
  interior { media { Media } }
  scale 1000
  hollow
  rotate y*120 rotate z*20
  }