// AGATE / Sphere No.5 '05.08
// By Tsutomu HIGO  URL: http://www.asahi-net.or.jp/~nj2t-hg/

#version 3.6;
global_settings {
  max_trace_level 4
  assumed_gamma 2.2
  }

#include "functions.inc"

camera {
  location <0, -15, 1000>
  look_at <0, 0, 0>
  angle 50
  }

union {
  isosurface {
    function { sqrt(x*x+y*y+z*z) -150 
      -f_agate(0.2*(x/sqrt(x*x+y*y+z*z)), 0.2*(y/sqrt(x*x+y*y+z*z)), 0.2*(z/sqrt(x*x+y*y+z*z))) *150 }
    contained_by { box { -2.5*350, 2.5*350 } }
    accuracy 1
    max_gradient 100
    pigment{ color rgbt <0, 0, 0, 0.9> }
    finish { ambient 0.2 reflection 0.7 phong 0.3 diffuse 1 }
    rotate y*230 rotate x*60
    no_shadow
    }

  #declare Media = media {
    emission 0.05
    intervals 5
    samples 1, 10
    confidence 0.9999
    variance 1/1000
    density {
      spherical
      ramp_wave
      turbulence 0.01
      color_map {
        [0.1  color rgb <0, 0, 0>]
        [0.3  color rgb <0, 0.05, 0.1>]
        [0.34 color rgb <0.05, 0.05, 0.05>]
        [0.4  color rgb <0, 0, 0>]
        }
      }
    }

  sphere { 0, 1
    pigment { color rgbf <1, 1, 1, 1> }
    finish { ambient 0 diffuse 0 }
    interior { media { Media } }
    scale 460
    hollow
    }

  rotate y*90 rotate z*-10
  }