// AGATE / Sphere No.4 '05.08
// By Tsutomu HIGO  URL: http://www.asahi-net.or.jp/~nj2t-hg/

#version 3.6;
global_settings {
  max_trace_level 4
  assumed_gamma 2.2
  }

#include "functions.inc"

camera {
  location <1, 3, -130>
  look_at <-3, 4, 0>
  angle 60
  }

isosurface {
  function { sqrt (x*x+y*y+z*z) -8 -f_agate (0.3*x, 0.3*y, 0.3*z) *10 }
  threshold 0
  accuracy 1
  max_gradient 1000
  contained_by { box { <-30, -30, -300>, <30, 30, 30> } }
  texture {
    pigment { color rgb <0.1, 0.3, 0.5> }
    finish {
      ambient 1
      diffuse 1
      reflection 0.3
      specular 1
      phong 0.1
      brilliance 1
      }
    }
  scale <2.5, 1.8, 1.8>
  rotate <20, 30, 40>
  no_shadow
  }

  #declare Media = media {
    emission 0.05
    intervals 5
    samples 1, 10
    confidence 0.9999
    variance 1/1000
    density {
      spherical
      ramp_wave
      turbulence 0.01
      color_map {
        [0.1  color rgb <0, 0, 0>]
        [0.23 color rgb <0, 0.05, 0.1>]
        [0.3  color rgb <0, 0.1, 0.3>]
        [0.8  color rgb <1, 1, 1>]
        }
      }
    }

  sphere { 0, 1
    pigment { color rgbf <1, 1, 1, 1> }
    finish { ambient 0 diffuse 0 }
    interior { media { Media } }
    scale 80
    hollow
    scale <1.0, 1.2, 0.8>
    rotate <-20, -20, -20>
    }