// AGATE / Horizon No.1 '05.08
// By Tsutomu HIGO  URL: http://www.asahi-net.or.jp/~nj2t-hg/

#version 3.6;
global_settings {
  max_trace_level 6
  assumed_gamma 2.2
  }

#include "functions.inc"

camera {
  location <0, -15, 1000>
  look_at <-100, 300, 50>
  angle 14
  }

union {
  isosurface { function { sqrt (x*x+y*y+z*z) -225 -f_agate (0.03*x, 0.03*y, 0.03*z) *125 }
  contained_by { box {-2.5*350, 2.5*350} }
  accuracy 1
  max_gradient 1000
    pigment{ color rgb <1, 1, 1> }
    finish { ambient 0.2 reflection 0.7 phong 0.3 diffuse 1 }
    rotate y*230 rotate x*23.45
    no_shadow
    }

  #declare Media = media {
    emission 0.05
    intervals 5
    samples 1, 10
    confidence 0.9999
    variance 1/1000
    density {
      spherical
      ramp_wave
      turbulence 0.01
      color_map {
        [0.1  color rgb <0, 0, 0>]
        [0.23 color rgb <0, 0.05, 0.1>]
        [0.25 color rgb <0, 0.1, 0.3>]
        [0.3  color rgb <0.1, 0.1, 0.1>]
        }
      }
    }

  sphere { 0, 1
    pigment { color rgbf <1, 1, 1, 1> }
    finish { ambient 0 diffuse 0 }
    interior { media { Media } }
    scale 460
    hollow
    }

  rotate y*90 rotate z*-10
  }