// SUNKEN / Hexagon 4 '05.06
// By Tsutomu HIGO  URL: http://www.asahi-net.or.jp/~nj2t-hg/

#version 3.6;
global_settings {
  max_trace_level 4
  assumed_gamma 2.2
  }

camera {
  location <1, 3, -15>
  look_at <1, -4, 0>
  angle 90
  }

#declare fn_Pigm = function {
  pigment { hexagon
    color blue 1, color red 1, color green 1
    turbulence 0
    scale 4
    rotate y*45
    }
  }

isosurface {
  function {(y+100*fn_Pigm(x*(x*x+z*z)/5, y, z*(x*x+z*z)/5).gray*50/(x*x+z*z+30))*(y+6)}
  threshold 0
  max_gradient 1000
  contained_by {box {<-40, -20, -14>, <40, 6, 20>}}
  texture {
    pigment {color rgb <0.2, 0.2, 0.1>}
    finish {
      ambient 0.0001
      diffuse 1
      reflection 0.3
      specular 1
      phong 0.1
      brilliance 1
      }
    }
  scale y*0.5
  no_shadow
  }

#declare Media = media {
  emission 0.12
  intervals 20
  samples 1, 1
  confidence 0.9999
  variance 1/100
  density {
    spherical
    turbulence 0.2
    color_map {
      [0 color rgbt <0, 0, 0, 1>]
      [0.1 color rgb <0.05, 0.05, 0.07>]
      [0.9 color rgb <0.3, 0.4, 0.5>]
      [1 color rgbt <0, 0, 0, 1>]
      }
    rotate y*120
    scale 5
    }
  }

union {
  sphere { <10, 70, -20> 75
    pigment { color rgbf <1 ,1, 1, 1> }
    finish { ambient 0 diffuse 0 }
    interior { media { Media } }
    hollow
    scale 5
    rotate x*30 rotate z*10
    }
  }