// SUNKEN / Hexagon 3 '05.06
// By Tsutomu HIGO  URL: http://www.asahi-net.or.jp/~nj2t-hg/

#version 3.6;
global_settings {
  max_trace_level 4
  assumed_gamma 2.2
  }

camera {
  location <1, 3, -10>
  look_at <1, -3, 0>
  angle 100
  }

#declare fn_Pigm = function {
  pigment { hexagon
    color blue 1, color red 1, color green 1
    turbulence 0
    scale 0.5
    }
  }

isosurface {
  function {(y+10*fn_Pigm(x+y, x, z+y).gray*50/(x*x+z*z+30))*(y+6)-3}
  threshold 0
  max_gradient 1000
  contained_by {box {<-40, -3, -12>, <40, 6, 30>}}
  texture {
    pigment {color rgb <0.2, 0.2, 0.1>}
    finish {
      ambient 0.0001
      diffuse 1
      reflection 0
      specular 1
      phong 0.1
      brilliance 1
      }
    }
  scale y*2.5
  rotate y*-15
  no_shadow
  }

#declare Media = media {
  emission 0.2
  intervals 20
  samples 1, 1
  confidence 0.9999
  variance 1/100
  density {
    spherical
    turbulence 0.2
    color_map {
      [0 color rgbt <0, 0, 0, 1>]
      [0.1 color rgb <0.05, 0.05, 0.07>]
      [0.9 color rgb <0.2, 0.3, 0.2>]
      [1 color rgbt <0, 0, 0, 1>]
      }
    scale 5
    }
  }

union {
  sphere { <10, 70, -10> 75
    pigment { color rgbf <1 ,1, 1, 1> }
    finish { ambient 0 diffuse 0 }
    interior { media { Media } }
    hollow
    scale 4
    rotate x*30 rotate z*10
    }
  }