// SUNKEN / Gradient '05.06
// By Tsutomu HIGO  URL: http://www.asahi-net.or.jp/~nj2t-hg/

#version 3.6;
global_settings {
  max_trace_level 4
  assumed_gamma 2.2
  }

camera {
  location <3, 10, -20>
  look_at <3, -2, 0>
  angle 80
  }

#declare fn_Pigm = function {
  pigment {
    gradient x
    pigment_map {
      [0 color <1,1,1>]
      [0.6 color <0,0,1>]
      }
    scale 3
    rotate y*45
    }
  }

isosurface {
  function { (y+150*fn_Pigm(x, y, z).gray*0.6/(x*x+z*z+30))*(y+5)+4 }
  threshold 5
  max_gradient 600
  contained_by {box {<-60, -3, -20>, <60, 10, 40>}}
  texture {
    pigment {color rgb <0.4, 0.4, 0.4>}
    finish {
      ambient 0.0001
      diffuse 1
      reflection 0.5
      specular 1
      phong 0.5
      brilliance 1
      }
    }
  scale y*3
  no_shadow
  }

#declare Media = media {
  emission 0.06
  intervals 20
  samples 1, 1
  confidence 0.9999
  variance 1/100
  density {
    spherical
    turbulence 0.25
    color_map {
      [0 color rgb <0, 0, 0>]
      [0.1 color rgb <0.4, 0.4, 0>]
      [0.3 color rgb <0.3, 0.3, 0.3>]
      [1 color rgb <0.5, 0.2, 0.2>]
      }
    scale 5
    }
  }

union {
  sphere { <0, 10, -10> 90
    pigment { color rgb <0.6, 0.6, 0.6> }
    finish { ambient 0 diffuse 0 }
    interior { media { Media } }
    hollow
    scale 8
    rotate x*160 rotate z*10
    }
  }