// SUNKEN / Checker '05.06
// By Tsutomu HIGO  URL: http://www.asahi-net.or.jp/~nj2t-hg/

#version 3.6;
global_settings {
  max_trace_level 4
  assumed_gamma 2.2
  }

camera {
  location <1, 3, -15>
  look_at <1, -10, 0>
  angle 100
  }

light_source {<30, 40, -50> color rgb <0, 0, 1>}

#declare fn_Pigm = function {
  pigment { checker
    color rgb <1, 1, 1>, color rgb <1, 0, 0>
    turbulence 0
    rotate y*30
    }
  }

isosurface {
  function { (y+800*fn_Pigm(x, y, z).gray*0.8/(x*x+z*z+50))*(y+5)+1 }
  threshold 5
  max_gradient 1000
  contained_by {box {<-50, -3, -20>, <50, 10, 10>} }
  texture {
    pigment {color rgb <1, 1, 1>}
    finish {
      ambient 0.0001
      diffuse 1
      reflection 0.5
      specular 1
      phong 0.5
      brilliance 1
      }
    }
  no_shadow
  }

#declare Media = media {
  emission 0.08
  intervals 20
  samples 1, 1
  confidence 0.9999
  variance 1/100
  density {
    spherical
    turbulence 0.5
    color_map {
      [0 color rgbt <0, 0, 0, 0.8>]
      [0.1 color rgb <0.1, 0.3, 0.1>]
      [0.5 color rgb <0.5, 0.5, 0>]
      [1 color rgb <1, 1, 1>]
      }
    scale 8
    }
  }

union {
  sphere { <0, 0, 0> 90
    pigment { color rgb <0.6, 0.6, 0.6> }
    finish { ambient 0 diffuse 0 }
    interior { media { Media } }
    hollow
    scale 2
    rotate x*160 rotate z*10
    }
  }