// HILL / Leopard '05.06
// By Tsutomu HIGO  URL: http://www.asahi-net.or.jp/~nj2t-hg/

#version 3.5;
global_settings {
  max_trace_level 4
  assumed_gamma 2.2
  }

camera {
  location <1, 6, -15>
  look_at <1, 5.5, 0>
  angle 64
  }

light_source { <10, 30, 5> color rgb <0.8, 0.8, 0.8> }

#declare fn_Pigm = function {
  pigment { leopard
    turbulence 0.6
    color_map {
      [0 color rgb 0]
      [1 color rgb 1]
      }
    scale 0.5
    }
  }

isosurface {
  function { (y-2*fn_Pigm(x+y, x, z).gray*50/(x*x+z*z+10))*(y+6)-3 }
  threshold 5
  max_gradient 100
  contained_by { box { <-12, -3, -12>, <12, 10, 12> } }
  texture {
    pigment { color rgb <0.2, 0.2, 0.1> }
    finish {
      ambient 0.0001
      diffuse 1
      reflection 0
      specular 1
      phong 0.1
      brilliance 1
      }
    }
  scale y*2.5
  rotate <0, 90, 0>
  no_shadow
  }

#declare Media = media {
  emission 0.15
  intervals 20
  samples 1, 1
  confidence 0.9999
  variance 1/100
  density {
    spherical
    turbulence 0.2
    color_map {
      [0 color rgbt <0, 0, 0, 1>]
      [0.1 color rgb <0.07, 0, 0>]
      [0.9 color rgb <0.4, 0.4, 0.2>]
      [1 color rgbt <0, 0, 0, 1>]
      }
    scale 5
    }
  }

union {
  sphere { <10, 70, -10> 75
    pigment { color rgbf <1 ,1, 1, 1> }
    finish { ambient 0 diffuse 0 }
    interior { media { Media } }
    hollow
    scale 4
    rotate x*30 rotate z*10
    }
  }