// HILL / Granite '05.06
// By Tsutomu HIGO  URL: http://www.asahi-net.or.jp/~nj2t-hg/

#version 3.5;
global_settings {
  max_trace_level 4
  assumed_gamma 2.2
  }

camera {
  location <1, 2, -9>
  look_at <1, -2, 0>
  angle 120
  }

light_source {<0, 50, 0> color rgb <1.8, 1, 0.7>}

#declare fn_Pigm = function {
  pigment { granite
    turbulence 0.7
    color_map {
      [0   color rgb 1]
      [0.7 color rgb 0]
      }
  scale 5
    }
  }

isosurface {
  function { (y-50*fn_Pigm(1.5*x, y, 0.5*z).gray*0.6/(x*x+z*z+4))*(y+5)+4 }
  threshold 5
  max_gradient 100
  contained_by {box {<-10, -3, -10>, <10, 10, 10>}}
  texture {
    pigment {color rgb <0.4, 0.4, 0.4>}
    finish {
      ambient 0.0001
      diffuse 1
      reflection 0
      specular 1
      phong 0.5
      brilliance 1
      }
    }
  scale y*1
  no_shadow
  }

#declare Media = media {
  emission 0.05
  intervals 20
  samples 1, 1
  confidence 0.9999
  variance 1/100
  density {
    spherical
    turbulence 0.5
    color_map {
      [0 color rgbt <0, 0, 0, 0.8>]
      [0.1 color rgb <0.2, 0.3, 0.25>]
      [0.5 color rgb <0.5, 0, 0>]
      [1 color rgbt <1, 0, 0, 0.8>]
      }
    scale 5
    }
  }

union {
  sphere { <0, 20, -10> 90
    pigment { color rgb <0.6, 0.6, 0.6> }
    finish { ambient 0 diffuse 0 }
    interior { media { Media } }
    hollow
    scale 4
    rotate x*160 rotate z*10
    }
  }