// HILL / Agate '05.06
// By Tsutomu HIGO  URL: http://www.asahi-net.or.jp/~nj2t-hg/

#version 3.5;
global_settings {
  max_trace_level 4
  assumed_gamma 2.2
  }

camera {
  location <1, 1, -4>
  look_at <4, 5, 0>
  angle 50
  }

light_source {<-50, 150, -75> color rgb <0.8, 0.8, 0.8>}

#declare fn_Pigm = function {
  pigment { agate
    turbulence 0.5
    color_map {
      [0   color rgb 1]
      [0.3 color rgb 0]
      }
    scale 1
    }
  }

isosurface {
  function { (y-5*fn_Pigm(x, y/5, z).gray*0.6/(x*x+z*z+0.1))*(y+5)+4 }
  threshold 5
  max_gradient 100
  contained_by {box {<-10, -3, -10>, <10, 10, 10>}}
  texture {
    pigment {color rgb <0.2, 0.2, 0.1>}
    finish {
      ambient 0.0001
      diffuse 1
      reflection 0
      specular 1
      phong 0.1
      brilliance 1
      }
    }
  scale y*3
  rotate <0, 90, -40>
  no_shadow
  }

#declare Media = media {
  emission 0.15
  intervals 20
  samples 1, 1
  confidence 0.9999
  variance 1/100
  density {
    spherical
    turbulence 0.2
    color_map {
      [0 color rgbt <0, 0, 0, 1>]
      [0.1 color rgb <0, 0, 0.1>]
      [0.9 color rgb <0.4, 0.3, 0.2>]
      [1 color rgbt <0, 0, 0, 1>]
      }
    scale 5
    }
  }

union {
  sphere { <0, 60, -10> 70
    pigment { color rgbf <0.1, 0.1, 0.1, 1> }
    finish { ambient 0 diffuse 0 }
    interior { media { Media } }
    hollow
    scale 3
    rotate x*30 rotate z*10
    }
  }