// REFRECT / Tetrahedron Mirrors '05.04
// By Tsutomu HIGO  URL: http://www.asahi-net.or.jp/~nj2t-hg/

#version 3.6;
global_settings {
  max_trace_level 30
  assumed_gamma 2.2
  }

camera {
  location <0, 0, -10.0>
  angle 140
  look_at <0, 0, 0>
  }

#declare R1 = seed(8);

union {
  light_source { <0, -50, -50> color rgb <1, 1, 0.8> }
  intersection {
    plane { -y, 0.204124145 }
    plane { y, 0.204124145 rotate z*180/pi*1.230959417 }
    plane { y, 0.204124145 rotate z*180/pi*1.230959417 rotate y*120 }
    plane { y, 0.204124145 rotate z*180/pi*1.230959417 rotate y*240 }
    bounded_by { box { <-0.7, -0.7, -0.7> <0.7, 0.7, 0.7> } }
    rotate y*80
    scale 30
    texture {
      pigment { color rgbt <0, 0, 0, 1> }
      finish { reflection 0.8 ambient 0.1 phong 0 brilliance 0 diffuse 0 }
      }
    }
  union {
  #declare I = 1; #while ( I<14 )
    sphere { <8*rand(R1)-5, 15*rand(R1), 8*rand(R1)> 1 rotate y*360*rand(R1) }
  #declare I = I+1; #end
    texture {
      pigment { color rgb <1, 1, 0.3> }
      finish {
        ambient 0.7
        reflection 0.8
        phong 1
        brilliance 3
        }
      }
    no_shadow
    }
  }