// TIME /  Frozen Time '05.02
// by Tsutomu HIGO  URL: http://www.asahi-net.or.jp/~nj2t-hg/

#version 3.6;
global_settings {
  max_trace_level 3
  assumed_gamma 2.2
  }

camera {
  location <-22, 0.5, -10>
  look_at <6, 6, 0>
  angle 64
  }

#declare Intensity = 8;
light_source {
  <160, 300, 126>
  color rgb <0.6, 1, 1> * Intensity
  spotlight
  point_at <-10.2, -5, -20>
  radius 20
  falloff 25
  tightness 15
  media_attenuation on
  }

#declare PREC = 5000000;
julia_fractal {
  <-0.503, -1.2, 0.4, 0.2>
  quaternion
  cube
  max_iteration 11
  precision PREC
  texture {
    pigment {color rgb <1, 1, 1>}
    finish {
      ambient 0
      diffuse 0.3
      reflection 0.5
      specular 0.8
      phong 0.5
      brilliance 1
      }
    }
  rotate <130, 40, -160>
  scale <15, 20, 15>
  }

background {color rgb <0.2, 0.3, 0.5>}

fog {
  fog_type 2
  distance 1000
  color rgb <0.5, 0.8, 1>
  fog_offset -2
  fog_alt 15
  turbulence 0.3
  }

plane { y, 0
  texture {
    pigment {color rgb <0, 0, 0>}
    finish {
      reflection 1
      ambient 0
      phong 1
      diffuse 0.5
      brilliance 1
      }
    normal {
      ripples 1
      scale 5
      frequency 15
      rotate y*30
      translate z*5
      turbulence 0.2
      }
    }
  no_shadow
  }