// TIME / Spinning '05.02
// by Tsutomu HIGO  URL: http://www.asahi-net.or.jp/~nj2t-hg/

#version 3.6;
global_settings {
  max_trace_level 3
  assumed_gamma 2.2
  }

camera {
  location <0, -35, -10>
  look_at <-15, -39, 0>
  angle 100
  }

#declare Intensity = 7;
light_source {
  <-600, 100, 600>
  color rgb <1, 1, 1> * Intensity
  spotlight
  point_at <0, 0, 0>
  radius 20
  falloff 50
  tightness 5
  media_attenuation on
  }

#declare PREC = 1000000;
julia_fractal {
  <-0.9, -0.4, -0.11, 0>
  quaternion
  cube
  max_iteration 11
  precision PREC
  texture {
    pigment {color rgb <1, 0.8, 0>}
    finish {
      ambient 0.1
      diffuse 0.3
      reflection 0.7
      specular 0.8
      phong 0.5
      brilliance 1
      }
    }
  rotate z*320 rotate y*320
  scale <120, 120, 120>
  translate <1, -30, 100>
  no_shadow
  }

fog {
  fog_type 2
  distance 700
  color rgb <0.7, 0.8, 1>
  fog_offset 10
  fog_alt 30
  turbulence 0.3
  }

plane { y, -40
  texture {
    pigment { color rgbt <0, 0.1, 0.03, 0.7> }
    finish {
      reflection 1
      ambient 0.5
      phong 1
      diffuse 0.5
      brilliance 1
      }
    normal {
      ripples 1
      scale <20, 10, 20>
      frequency 15
      translate <100, 20, -225>
      rotate y*60
      turbulence 0.1
      }
    }
  no_shadow
  }