// TIME /  Distorted Time '05.02
// by Tsutomu HIGO  URL: http://www.asahi-net.or.jp/~nj2t-hg/

#version 3.6;
global_settings {
  max_trace_level 3
  assumed_gamma 2.2
  }

camera {
  location <0, 200, -130>
  look_at <0, 0, -5>
  angle 64
  }

#declare Intensity = 4;
light_source {
  <-160, 300, 300>
  color rgb <0.6, 1, 1> * Intensity
  spotlight
  point_at <-10.2, 10, -20>
  radius 20
  falloff 25
  tightness 15
  media_attenuation on
  }

#declare PREC = 1000000;
julia_fractal {
  <-0.603, -0.6, -0.4, 0.4>
  quaternion
  cube
  max_iteration 11
  precision PREC
  texture {
    pigment {color rgb <1, 0.8, 0>}
    finish {
      ambient 0.1
      diffuse 0.3
      reflection 0.5
      specular 0.8
      phong 0.5
      brilliance 1
      }
    }
  rotate x*60 rotate y*310 rotate x*-60
  scale <100, 100, 100>
  translate <30, -20, 0>
  no_shadow
  }

background { color rgb <0, 0.3, 0.5> }

plane { y, 0
  texture {
    pigment { color rgbt <0, 0.2, 0.3, 0.4> }
    finish {
      reflection 0.6
      ambient 0
      phong 1
      diffuse 0.5
      brilliance 1
      }
    normal {
      ripples 1
      scale <1, 0.5, 1>
      frequency 15
      rotate y*30
      translate z*5
      turbulence 0.2
      }
    }
  no_shadow
  }