// WORLD / A Gate  '04.11
// by Tsutomu HIGO  URL: http://www.asahi-net.or.jp/~nj2t-hg/

#version 3.6;
global_settings {
  max_trace_level 4
  assumed_gamma 2.2
  }

camera {
  location <0, -10, 50>
  angle 68
  look_at <0.5, 6, 0>
  }

height_field {
  png "2004-27-a-full_jpg.png"
  smooth
  pigment {
    agate
    agate_turb 0.1
    turbulence 0.1
    color_map {
      [0.4 color rgbt <0, 0, 0, 0.9>]
      [0.5 color rgbt <1, 0, 0, 0.9>]
      [0.6 color rgbt <1, 0, 0, 0.9>]
      [0.7 color rgbt <1, 1, 1, 0.9>]
      }
    scale 0.2
    rotate x*90
    }
  finish {
   reflection 0
   ambient 1
   diffuse 0.5
   phong 2
   brilliance 1
   }
  translate <-0.5, -0.6, -0.5>
  scale <12000, 100, 240>
  rotate x*180 rotate y*30 translate y*-200 rotate z*10
  }

light_source { <2, 10, 2> color rgb <1, 0.6, 0.8> }

sphere { <0, 0, 0> 6
  scale <5, 3, 5>
  rotate <280, 50, -240>
  translate y*10
  pigment { rgbt <0, 0, 1, 0.8> }
  finish {
    reflection 0.6
    ambient 0.3
    diffuse 0.7
    phong 1.2
    phong_size 4
    }
  interior {
    ior 1.05
    fade_distance 20
    fade_power 3
    }
  no_shadow
  }

fog {
  fog_type 2
  distance 0.01
  color rgb <1, 0.9, 0.97>
  fog_offset -1
  fog_alt 1
  turbulence 0.3
  }

background { color rgb <0.3, 0.5, 1> }