// CITY / Returning  '04.06
// by Tsutomu HIGO  URL: http://www.asahi-net.or.jp/~nj2t-hg/

#version 3.5;
global_settings {
  max_trace_level 12
  assumed_gamma 2.2
  }

camera {
  location <0, 24, -18>
  angle 125.0
  look_at <0, -18, -10>
  }

height_field {
  png "ipctretn.png"
  smooth
  pigment {
    marble
    turbulence 0.5
    color_map {
      [0.5 color rgbt <0.1, 0.2, 0.4>]
      [0.8 color rgbt <0, 1, 0.3, 1>]
      [1 color rgbt <1, 1, 1, 0.5>]
      }
    scale 0.02
    rotate z*90
    }
  finish { reflection 0.2 ambient 0.1 diffuse 0.5 phong 0.5 brilliance 1 }
  translate <-0.5, -0.6, -0.5>
  scale <120, 15, 90> rotate y*0
  }

light_source { <0, 2, 0> color rgb <1, 1, 1> }

#declare Media = media {
  emission 0.02
  intervals 3
  samples 1, 1
  confidence 0.9999
  variance 1/100
  density {
    spherical
    turbulence 0.5
    color_map {
      [0 color rgbt <0, 0, 0, 1>]
      [0.2 color rgb <0.3, 0.3, 0>]
      [0.47 color rgb <1, 0.7, 0.5>]
      [1 color rgbt <0, 0, 0, 1>]
      }
    scale 10
    }
  rotate y*0
  }

sphere { 0, 100
  pigment { color rgbf <1, 1, 1, 1> }
  finish { ambient 0 diffuse 0 }
  interior { media { Media } }
  hollow
  rotate z*220 rotate x*260 rotate y*250
  scale 10
  translate <3, 0, -50>
  }

#declare Iend=28;
#declare An=50;
#declare X=0.1;
#declare Y=0.1;
#declare Z=0.1;
#declare A=1.5; #while (A<2.5)
#declare I=0; #while (I<Iend)
  #declare Tx=(A*X-X*X*X+Y);
  #declare Ty=(-A*3/8+1.1)*X;
  #declare Tz=A*X*Y;
  #declare X=Tx;
  #declare Y=Ty;
  #declare Z=Tz;
  #if (I>25)
  sphere {  <0,0,0> 0.2 scale <5,3,5> translate <30*X-10, 36*(Y-0.1)+1, 30*Z-2> rotate y*190
    pigment { rgbt<0, 0, 1, 0.9> }
    finish {
      ambient 0.3
      diffuse 0
      phong 1
      phong_size 200
      }
    interior {
      ior 1.05
      fade_distance 20
      fade_power 3
      }
    no_shadow
    }
  #end
#declare I=I+1; #end
#declare A=A+1/An; #end

fog {
  fog_type 2
  distance 2
  color rgb <1, 0.9, 0.97>
  fog_offset -1
  fog_alt 1
  turbulence 0.3
  }

background { color rgb <0.3, 0.5, 1> }