// CITY / At Noon  '04.06
// by Tsutomu HIGO  URL: http://www.asahi-net.or.jp/~nj2t-hg/

#version 3.5;
global_settings {
  max_trace_level 4
  assumed_gamma 2.2
  }

camera {
  location <-0, -6, -14>
  angle 138.0
  look_at <0,-15, 0>
  }

height_field {
  png "ipctnoon.png"
  smooth
  pigment {
    marble
    turbulence 0.3
    color_map {
      [0.5 color rgbt <0.1, 0.4, 0.1>]
      [0.8 color rgbt <0, 0, 0.7, 1>]
      [1 color rgbt <1, 1, 1,0.5>]
      }
    scale 0.02
    rotate z*90
    }
  finish { reflection 0.6 ambient 0.3 diffuse 0.5 phong 0.5 brilliance 1 }
  translate <-0.5, -0.95, -0.5>
  scale <40, 12, 30>
  }

light_source { <5, 10, 10> color rgb <1, 1, 1> }

#declare Media = media {
  emission 0.02
  intervals 3
  samples 1, 1
  confidence 0.9999
  variance 1/100
  density {
    spherical
    turbulence 0.5
    color_map {
      [0 color rgbt <0, 0, 0, 1>]
      [0.2 color rgb <0.3, 0.3, 0>]
      [0.47 color rgb <1, 0.7, 0.5>]
      [1 color rgbt <0, 0, 0, 1>]
      }
    scale 10
    }
  }

sphere { 0, 100
  pigment { color rgbf <1, 1, 1, 1> }
  finish { ambient 0 diffuse 0 }
  interior { media { Media } }
  hollow
  rotate z*220 rotate x*260 rotate y*250
  scale 4
  translate <3, 20, -2>
  }

#declare Iend=200;
#declare An=50;
#declare X=0.1;
#declare Y=0.1;
#declare Z=0.1;
#declare A=1.5; #while (A<2.5)
#declare I=0; #while (I<Iend)
  #declare Tx=(A*X-X*X*X+Y);
  #declare Ty=(-A*3/8+1.1891)*X;
  #declare Tz=A*X*Y;
  #declare X=Tx;
  #declare Y=Ty;
  #declare Z=Tz;
  sphere {  <0,0,0> 0.2 scale <1,0.3,1> translate <26*X, 26*(Y-0.1), 26*Z> rotate y*9 translate x*16
    pigment { color rgb <1,0.7,0.6> filter 0.99 }
    interior{
      ior 1.45
      fade_distance 10
      fade_power 0.1
      caustics 2.0
      }
    finish { reflection 0.7 ambient 0.2 phong 1 brilliance 1 diffuse 2 }
    rotate y*235
    no_shadow
    }
#declare I=I+1; #end
#declare A=A+1/An; #end

fog {
  fog_type 2
  distance 12
  color rgb <0.7, 0.8, 1>
  fog_offset 0.8
  fog_alt 0.1
  turbulence 0.8
  }

background { color rgb <1, 0.8, 0.7> }