// CITY / A Gate  '04.06
// by Tsutomu HIGO  URL: http://www.asahi-net.or.jp/~nj2t-hg/

#version 3.5;
global_settings {
  max_trace_level 7
  assumed_gamma 2.2
  }

camera {
  location <20, -60, -20>
  angle 60.0
  look_at <-15, 40, 5>
  }

height_field {
  png "ipctgate.png"
  smooth
  pigment { color rgbt <0.5, 0.5, 0.3, 0.8> }
  finish { reflection 0.6 ambient 0.2 diffuse 0.5 phong 1.7 brilliance 1 }
  scale <120, 200, 90>
  translate <-60, -100, -45>
  rotate y*50 rotate x*200
  }

light_source { <0, 0, 0> color rgb <1, 1, 1> }

#declare Media = media {
  emission 0.003
  intervals 3
  samples 1, 1
  confidence 0.9999
  variance 1/100
  density {
    spherical
    turbulence 0.5
    color_map {
      [0 color rgbt <0, 0, 0, 1>]
      [0.2 color rgb <0.3, 0.3, 0>]
      [0.47 color rgb <1, 0.7, 0.5>]
      [1 color rgbt <0, 0, 0, 1>]
      }
    scale 15
    }
  }

sphere { 0, 100
  pigment { color rgbf <1, 1, 1, 1> }
  finish { ambient 0 diffuse 0 }
  interior { media { Media } }
  hollow
  rotate z*220 rotate x*260 rotate y*250
  scale 4
  translate <3, 20, -2>
  }

#declare Iend=10;
#declare An=50;
#declare X=0.1;
#declare Y=0.1;
#declare Z=0.1;
#declare A=1.5; #while (A<2.5)
#declare I=0; #while (I<Iend)
  #declare Tx=(A*X-X*X*X+Y);
  #declare Ty=(-A*3/8+1.1891)*X;
  #declare Tz=A*X*Y;
  #declare X=Tx;
  #declare Y=Ty;
  #declare Z=Tz;
  sphere { <0,0,0> 0.1 scale 5 translate <30*X, 30*Y, 30*Z> rotate y*5 translate <12,-40,-5>
    pigment { color rgbt <1, 0.7, 0.6, 0.9> filter 0.99 }
    finish {
      ambient 0.3
      diffuse 0
      phong 1
      phong_size 200
      }
    interior {
      ior 1.05
      fade_distance 20
      fade_power 3
      }
    no_shadow
    }
#declare I=I+1; #end
#declare A=A+1/An; #end