// CITY / In The Evening  '04.06
// by Tsutomu HIGO  URL: http://www.asahi-net.or.jp/~nj2t-hg/

#version 3.5;
global_settings {
  max_trace_level 4
  assumed_gamma 2.2
  }

camera {
  location <-5, -4, -20>
  angle 100.0
  look_at <0,-15, 0>
  }

height_field {
  png "ipcteven.png"
  smooth
  pigment {
    marble
    turbulence 0.2
    color_map {
      [0.5 color rgb <1, 1, 1>]
      [0.8 color rgb <0, 0, 0.1>]
      [1 color rgb <1, 1, 1>]
      }
    scale 0.003
    rotate z*90
    }
  finish { reflection 0.9 ambient 0.3 diffuse 0.5 phong 0.5 brilliance 1 }
  translate <-0.5, -0.6, -0.5>
  scale <120, 60, 90>
  rotate y*-10
  }

light_source { <5, 10, 10> color rgb <1, 1, 1> }

#declare Iend=30;
#declare An=50;
#declare X=0.1;
#declare Y=0.1;
#declare Z=0.1;
#declare A=1.5; #while (A<2.5)
#declare I=0; #while (I<Iend)
  #declare Tx=(A*X-X*X*X+Y);
  #declare Ty=(-A*3/8+1.1)*X;
  #declare Tz=A*X*Y;
  #declare X=Tx;
  #declare Y=Ty;
  #declare Z=Tz;
  sphere {  <0,0,0> 0.1 scale <2,0.3,1> translate <20*X, 30*(Y-0.1), 20*Z> rotate y*9 translate x*16
    pigment { color rgbt <1,1,1,1> filter 0.01 }
    interior{
      ior 0.05
      fade_distance 100
      fade_power 0.01
      caustics 2
      }
    finish { reflection 0 ambient 0.2 phong 0 brilliance 1 diffuse 2 }
    rotate y*235
    translate <1, 3, 1.5>
    no_shadow
    }
#declare I=I+1; #end
#declare A=A+1/An; #end

fog {
  fog_type 2
  distance 20
  color rgb <1, 0.85, 0.7>
  fog_offset -2
  fog_alt 0.1
  turbulence 0.8
  }

background { color rgb <0, 0, 0.2> }