// CITY / Dreaming  '04.06
// by Tsutomu HIGO  URL: http://www.asahi-net.or.jp/~nj2t-hg/

#version 3.5;
global_settings {
  max_trace_level 10
  assumed_gamma 2.2
  }

camera {
  location <-2, 18, -24>
  angle 103.0
  look_at <-2,-18, -12>
  }

height_field {
  png "ipctdrem.png"
  smooth
  pigment { color rgbt <0.1, 0.2, 0.4, 0.8>}
  finish { reflection 0.1 ambient 0.3 diffuse 0.5 phong 0 brilliance 1 }
  translate <-0.5, -0.6, -0.5>
  scale <120, 50, 90>
  rotate x*0
  }

light_source { <0, 2, 0> color rgb <1, 1, 1> }  

#declare Media = media {
  emission 0.02
  intervals 3
  samples 1, 1
  confidence 0.9999
  variance 1/100
  density {
    spherical
    turbulence 0.5
    color_map {
      [0 color rgb <0, 0, 0>]
      [0.4 color rgb <0, 0, 1>]
      [0.7 color rgb <0, 1, 0>]
      [1 color rgbt <1, 1, 1, 1>]
      }
    scale 10
    }
  }

sphere { 0, 100
  pigment { color rgbf <1, 1, 1, 1> }
  finish { ambient 0 diffuse 0 }
  interior { media { Media } }
  hollow
  rotate z*220 rotate x*260 rotate y*250
  scale 3
  translate <0, 0, -10>
  }

#declare Iend=5;
#declare An=50;
#declare X=0.1;
#declare Y=0.1;
#declare Z=0.1;
#declare A=1.5; #while (A<2.5)
#declare I=0; #while (I<Iend)
  #declare Tx=(A*X-X*X*X+Y);
  #declare Ty=(-A*3/8+1.1)*X;
  #declare Tz=A*X*Y;
  #declare X=Tx;
  #declare Y=Ty;
  #declare Z=Tz;
  sphere {  <0,0,0> 0.2 scale 5 translate <40*X, 80*(Y-0.1), 40*Z> translate <-10,0,0> rotate y*130
    pigment { rgbt<0, 0, 1, 0.9> }
    finish {
      ambient 0.3
      diffuse 0
      phong 1
      phong_size 200
      }
    interior {
      ior 1.05
      fade_distance 20
      fade_power 3
      }
    no_shadow
    }
#declare I=I+1; #end
#declare A=A+1/An; #end

fog {
  fog_type 2
  distance 1
  color rgb <0.6, 0.7, 1>
  fog_offset -20
  fog_alt 1
  turbulence 0.3
  }

background { color rgb <0.3, 0.5, 1> }