// AIR / Blue City  '04.04
// by Tsutomu HIGO  URL: http://www.asahi-net.or.jp/~nj2t-hg/

#version 3.5;
global_settings {
  max_trace_level 4
  assumed_gamma 2.2
  }

camera {
  location <0.25, 0.6, -1>
  angle 110.0
  look_at <-1.6, 0.9, 0>
  }

height_field {
  tga "iparbcty.tga"
  smooth
  pigment {
    marble
    turbulence 0
    color_map {
      [0 color rgb <0, 0, 0>]
      [0.5 color rgb <0.6, 1, 0.8>]
      [1 color rgb <1, 1, 1>]
      }
    scale 0.005
    rotate z*90
    }
  finish { reflection 1 ambient 0.15 diffuse 0.5 brilliance 1 phong 1 }
  translate <-0.5, 0, -0.5>
  scale <4, 1.5, 3>
  }

light_source {<500, 2000, 100> color <1, 1, 1>}

#declare Media = media {
  emission 0.1
  intervals 3
  samples 1, 1
  confidence 0.9999
  variance 1/100
  density {
    spherical
    turbulence 0.5
    color_map {
      [0 color rgbt <0, 0, 0, 1>]
      [0.4 color rgb <0, 0, 0.5>]
      [0.67 color rgb <1, 0.9, 0.7>]
      [1 color rgbt <0, 0, 0, 1>]
      }
    scale 5
    }
  }

sphere { 0, 100
  pigment { color rgbf <1, 1, 1, 1> }
  finish { ambient 0 diffuse 0 }
  interior { media { Media } }
  hollow
  rotate z*220 rotate x*260 rotate y*240
  scale 2
  translate <0.5, -1, 0>
  }