// CHERRY / Spheres in the red  '04.04
// by Tsutomu HIGO  URL: http://www.asahi-net.or.jp/~nj2t-hg/

#version 3.5;
global_settings {
  max_trace_level 4
  assumed_gamma 2.2
  }

camera {
  location <-0, -80, -500>
  angle 118
  look_at <80, 380, 0>
  }

#declare Media = media {
  emission 0.08
  intervals 20
  samples 1, 1
  confidence 0.9999
  variance 1/100
  density {
    crackle
    turbulence 0.2
    color_map {
      [0.50 color rgbt <0, 0, 0, 1>]
      [0.60 color rgb <0, 0.2, 0.5>]
      [0.65 color rgb <1, 1, 1>]
      [0.75 color rgb <0.5, 0.5, 0>]
      [0.9 color rgbt <0, 0, 0, 1>]
      }
    scale <5, 30, 10>
    }
  }

#declare Spheres = union {
  #declare I = 0; #while (I < 9)
    sphere { 0, 11 scale <1, 2, 1> rotate z*30 translate <40, 20, 0> rotate y*40*I }
  #declare I = I+1; #end
  pigment { color rgb<0.6, 0.5, 0.4> }
  finish { ambient 0.3 diffuse 0.5 phong 1 reflection 0.3}
  }

union {
  sphere { 0, 500 scale <2, 0.5, 2>
    pigment { color rgbf <1, 1, 1, 1> }
    finish { ambient 0 diffuse 0 }
    interior { media { Media } }
    hollow
    }
  union { Spheres scale 10}
  rotate <10, 0, -10>
  }

background { color rgb <1, 0, 0> }