// CHERRY / Rings in the sky  '04.04
// by Tsutomu HIGO  URL: http://www.asahi-net.or.jp/~nj2t-hg/

#version 3.5;
global_settings {
  max_trace_level 4
  assumed_gamma 2.2
  }

camera {
  location <-40, -50, -120>
  angle 110
  look_at <-20, -35, 0>
  }

#declare Media = media {
  emission 0.2
  intervals 60
  samples 1, 1
  confidence 0.9999
  variance 1/100
  density {
    crackle
    turbulence 0.3
    color_map {
      [0.58 color rgbt <0, 0, 0, 1>]
      [0.6 color rgbt <1, 1, 1, 1>]
      [0.65 color rgb <1, -0.6, -0.6>]
      [0.7 color rgb <1, 1, 1>]
      [0.8 color rgb <0, -0.9, 0>]
      [0.85 color rgbt <1, 1, 1, 1>]
      }
    scale <2, 10, 2> rotate z*-30 rotate y*-30
    }
  }

#declare Ring =
  intersection {
    cylinder { <0, 0, 0> <0, 0, 3>, 30 }
    cylinder { <0, 0, -1> <0, 0, 4>, 27 inverse }
    box { <-24, 0, -1> <24, 31, 4> inverse }
    pigment { color rgb<1, 1, 0.5> }
    finish { ambient 0.6 diffuse 0.5 phong 0.3 reflection 0.2 }
    scale 5
    }

union {
  cylinder { <0, 0, -60> <0, 0, 100>, 125
    pigment { color rgbf <1, 1, 1, 1> }
    finish { ambient 0 diffuse 0 }
    interior { media { Media } }
    hollow
    }
  #declare I = 0; #while (I < 50)
    object { Ring translate z*I*100 }
  #declare I = I+1; #end
  }

background { color rgb <0.75, 0.8, 1> }