// CHERRY / Pipes in the dark  '04.04
// by Tsutomu HIGO  URL: http://www.asahi-net.or.jp/~nj2t-hg/

#version 3.5;
global_settings {
  max_trace_level 4
  assumed_gamma 2.2
  }

camera {
  location <10, 0, -300>
  angle 55
  look_at <5, -10, 0>
  }

#declare Media = media {
  emission 0.1
  intervals 10
  samples 1, 1
  confidence 0.9999
  variance 1/100
  density {
    crackle
    turbulence 0.3
    color_map {
      [0.45 color rgbt <0, 0, 0, 1>]
      [0.5 color rgb <0, 0, 1>]
      [0.55 color rgb <1, 1, 1>]
      [0.7 color rgb <1, 0, 0>]
      [0.9 color rgbt <0, 0, 0, 1>]
      }
    scale 5
    }
  } 

#declare Pole =
  cylinder { <60, 0, 0> <60, 0, 3000>, 9 open
  pigment { color rgbt <0, 1, 0, 0.4> }
  finish { ambient 0.3 diffuse 0.5 phong 0.3 reflection 1 }
  }

union {
  sphere { 0, 160 scale <0.5, 0.5, 1.8>
    pigment { color rgbf <1, 1, 1, 1> }
    finish { ambient 0 diffuse 0 }
    interior { media { Media } }
    hollow
    }
  #declare I = -2; #while (I < 12)
    object { Pole translate x*I*3 rotate z*(30.8*I+10) translate z*-20*I }
  #declare I = I+1; #end
  }