// CHERRY / Orange in the dark  '04.04
// by Tsutomu HIGO  URL: http://www.asahi-net.or.jp/~nj2t-hg/

#version 3.5;
global_settings {
  max_trace_level 4
  assumed_gamma 2.2
  }

camera {
  location <0, 6, -10>
  angle 56
  look_at <0, -1, 0>
  }

#declare Media = media {
  emission 0.2
  intervals 10
  samples 1, 1
  confidence 0.9999
  variance 1/100
  density {
    crackle
    solid
    turbulence 0.2
    color_map {
      [0.5 color rgbt <0, 0, 0, 1>]
      [0.6 color rgb <0, 0.3, 0>]
      [0.67 color rgb <1, 1, 1>]
      [0.6 color rgb <0, 0, 1>]
      [0.7 color rgbt <0, 0, 0, 1>]
      }
    scale 0.3
    }
  }

union {
  sphere { 0, 10
    pigment { color rgbf <1, 1, 1, 1> }
    finish { ambient 0 diffuse 0 }
    interior { media { Media } }
    hollow
    }
  union {
    #declare I = 0; #while (I < 9)
      intersection {
        sphere { <0, 0, 0>, 3 }
        box{ <0, -4, 0> <4, 4, 4> rotate y*45 scale <1/tan(pi/180*15), 1, 1> }
        rotate z*-45 translate x*3*pi*45/180 rotate y*40*I
        }
    #declare I = I+1; #end
    pigment { color rgb <1, 0.2, 0> }
    finish { ambient 1 diffuse 1.5 reflection 1 }
    }
  rotate z*-6
  }