// CHERRY / Coil in the dark  '04.04
// by Tsutomu HIGO  URL: http://www.asahi-net.or.jp/~nj2t-hg/

#version 3.5;
global_settings {
  max_trace_level 4
  assumed_gamma 2.2
  }

camera {
  location <10, 0, -240>
  angle 120
  look_at <30, -160, 0>
  }

#declare Media = media {
  emission 0.05
  intervals 50
  samples 1, 1
  confidence 0.9999
  variance 1/100
  density {
    crackle
    turbulence 0.2
    color_map {
      [0.45 color rgbt <0, 0, 0, 1>]
      [0.55 color rgb <0, 0, 1>]
      [0.65 color rgb <1, 1, 1>]
      [0.75 color rgb <0, 1, 0>]
      [1 color rgbt <0, 0, 0, 1>]
      }
    scale 20
    }
  }

#declare coil =  merge {
  intersection {
    box { <-2, -2, -2>, <2, 2, 0> }
    sphere { <0, 0, 0>, 0.3 }
    }
  #declare I = 1; #while (I < 24)
    intersection {
      box { <-2*I-2, -2*I-2, (-2*I-2)*(0.5+0.5*pow(-1,I))>, <2*I+2, 2*I+2, (2*I+2)*(0.5+0.5*pow(-1,I+1))> }
      torus { 2*I, 0.3 }
      translate x*(-1+pow(-1,I))
      }
  #declare I = I+1; #end
  pigment { color rgbt <0.3, 0.3, 1, 0.3> }
  finish { ambient 0.3 diffuse 0.5 phong 0.3 reflection 1 }
  }

union {
  sphere { 0, 500 scale <2, 0.15, 2>
    pigment { color rgbf <1, 1, 1, 1> }
    finish { ambient 0 diffuse 0 }
    interior { media { Media } }
    hollow
    }
  object { coil scale 10 }
  rotate x*-36 rotate z*10
  }