// CHERRY / Boxes in the dark  '04.04
// by Tsutomu HIGO  URL: http://www.asahi-net.or.jp/~nj2t-hg/

#version 3.5;
global_settings {
  max_trace_level 4
  assumed_gamma 2.2
  }

camera {
  location <-100, 0, -40>
  angle 90
  look_at <0, 150, 150>
  }

#declare Media = media {
  emission 0.05
  intervals 50
  samples 1, 1
  confidence 0.9999
  variance 1/100
  density {
    crackle
    turbulence 0.3
    color_map {
      [0.45 color rgbt <0, 0, 0, 1>]
      [0.55 color rgb <1, 0, 0>]
      [0.65 color rgb <1, 1, 1>]
      [0.75 color rgb <0, 1, 0>]
      [1 color rgbt <0, 0, 0, 1>]
      }
    scale 10
    }
  }

#declare Towers = union {
  #declare I = 0; #while (I < 6)
    #declare J = 0; #while (J < 3)
      box { <-1, 4, -1>, <1, 12, 1> translate <4*(I-3), 0, 4*J> }
    #declare J = J+1; #end
  #declare I = I+1; #end
  pigment { color rgbt <0.3, 0.3, 1, 0.8> }
  finish { ambient 0.6 diffuse 0.5 phong 0.3 reflection 1 }
  }

union {
  box { <-130, -30, -50>, <130, 150, 120>
    pigment { color rgbf <1, 1, 1, 1> }
    finish { ambient 0 diffuse 0 }
    interior { media { Media } }
    hollow
    }
  union { Towers scale 10}
  }