// SURROUND /  like a hit apple '04.03
// by Tsutomu HIGO  E-mail: nj2t-hg@asahi-net.or.jp

#version 3.5;
global_settings {
  max_trace_level 4
  assumed_gamma 2.2
  }

camera {
  location <0, 0, -20>
  angle 30
  look_at <0.7, 0.5, 0>
  }

#declare Mediab = media {
  emission 0.5
  intervals 100
  samples 1, 1
  confidence 0.1
  variance 1/200
  density {
    spherical
    turbulence 0.3
    color_map {
      [0 color rgbt <0, 0, 0, 1>]
      [0.3 color rgb <0, 0, 0.3>]
      [0.5 color rgb <0.5, 0.5, 0.5>]
      [1 color rgbt <0, 0, 0, 1>]
      }
    scale 5
    }
  }

#declare Mediar = media {
  emission 0.5
  intervals 100
  samples 1, 1
  confidence 0.1
  variance 1/200
  density {
    spherical
    turbulence 0.6
    color_map {
      [0 color rgbt <0, 0, 0, 1>]
      [0.3 color rgb <0.5, 0, 0>]
      [0.7 color rgb <0.5, 0.5, 0.5>]
      [1 color rgbt <0, 0, 0, 1>]
      }
    scale 5
    }
  }

union {
  sphere {<0, 0, 0>, 1200
    pigment { color rgbf <1, 1, 1, 1> }
    finish { ambient 0 diffuse 0 }
    interior { media { Mediab } }
    hollow
    }
  sphere { <0, 0, 0>, 1200
    pigment { color rgbf <1, 1, 1, 1> }
    finish { ambient 0 diffuse 0 }
    interior { media { Mediar } }
    hollow
    scale <2, 0.2, 0.2>
    rotate y*40 rotate x*30
    }
  sphere { <0, 0, 0>, 2.4
    pigment { color rgb <0, 0, 0> }
    finish { ambient 0 diffuse 1.5 reflection 1 }
    }
  rotate z*15
  }