// INT '03.07 / Yellow
// By Tsutomu HIGO  URL: http://www.asahi-net.or.jp/~nj2t-hg/

#version 3.5;
global_settings {
  max_trace_level 4
  assumed_gamma 2.2
  }

camera {
  location <0.5, 2.2, -0.3>
  look_at <-0.3, 0, 0.1>
  angle 120
  }

light_source {<600, 550, 50> color rgb <0.8, 0.8, 0.8>}

isosurface {
  #declare Rl=1.5;
  #declare Rs=0.1;
  #declare Diva=32;
  #declare Py=0.3;
  #declare Pa=2*pi/Diva;
  function {
    (pow(x-Rl*                  cos(Pa*int(acos(x/sqrt(x*x+z*z+0.000001))/Pa+1/2)),2)
    +pow(z-Rl*z/abs(z+0.000001)*sin(Pa*int(acos(x/sqrt(x*x+z*z+0.000001))/Pa+1/2)),2)
    +pow(y-0.3*(int(y/0.3)+0.5),2)-pow(Rs,2))
    *(x*x+9*pow(y-0.6,2)+z*z-1.38*1.38-0.2*cos(25*pi*pow(x*x+z*z+pow(y-1.38/3-0.6,2),2)+pi))
    -0.0004
    }
  threshold 0
  max_gradient 30
  contained_by {box {<-Rl-Rs-0.1, -Rs, -Rl-Rs-0.1>, <Rl+Rs+0.1, 1.8, Rl+Rs+0.1>}}
  open
  texture {
    pigment {color rgb <1, 0.8, 0>}
    finish {
      ambient 0.3
      diffuse 0.5
      reflection 0.3
      specular 1
      phong 0.5
      brilliance 1
      }
    }
  rotate z*-25 rotate y*10
  no_shadow
  }

background {color rgb <0, 0.3, 0.4>}