// INT '03.07 / Red
// By Tsutomu HIGO  URL: http://www.asahi-net.or.jp/~nj2t-hg/

#version 3.5;
global_settings {
  max_trace_level 4
  assumed_gamma 2.2
  }

camera {
  location <1, 1.2, -2>
  look_at <-0.2, -0.6, 0>
  angle 74
  }

light_source {<50, 350, -200> color rgb <0.8, 0.8, 0.8>}

isosurface {
  #declare Rl=1.5;
  #declare Rs=0.08;
  #declare Diva=32;
  #declare Pa=2*pi/Diva;
  function {
    (pow(x-Rl*                  cos(Pa*int(acos(x/sqrt(x*x+z*z+0.000001))/Pa+1/2)),2)
    +pow(z-Rl*z/abs(z+0.000001)*sin(Pa*int(acos(x/sqrt(x*x+z*z+0.000001))/Pa+1/2)),2)
    +pow(y,2)-pow(Rs,2))
    *(x*x+9*y*y+z*z-1.35*1.35-0.1*cos(50*pi*pow(x*x+z*z+(y-0.4)*(y-0.4),2)+pi))
    -0.0004
    }
  threshold 0
  max_gradient 5
  contained_by {box {<-Rl-Rs-0.1, -0.5, -Rl-Rs-0.1>, <Rl+Rs+0.1, 0.5, Rl+Rs+0.1>}}
  open
  texture {
    pigment {color rgb <1, 0.3, 0>}
    finish {
      ambient 0.3
      diffuse 0.5
      reflection 0.3
      specular 1
      phong 0.5
      brilliance 1
      }
    }
  rotate z*-25 rotate y*10
  no_shadow
  }

background {color rgb <1, 1, 1>}