// INT '03.07 / Black
// By Tsutomu HIGO  URL: http://www.asahi-net.or.jp/~nj2t-hg/

#version 3.5;
global_settings {
  max_trace_level 4
  assumed_gamma 2.2
  }

camera {
  location <0, 5, -3>
  look_at <0.1, 0.05, 0>
  angle 90
  }

light_source {<50, 120, 80> color rgb <0.8, 0.8, 0.8>}

#declare Isounit=
  isosurface {
    #declare Rs=0.18;
    #declare Diva=12;
    #declare Py=0.3;
    #declare Pa=2*pi/Diva;
    function {
      (pow(x-0.4*(int(sqrt(x*x+z*z)/0.4)+0.5)*cos(Pa*int(acos(x/sqrt(x*x+z*z+0.000001))/Pa+1/2)),2)
      +pow(z-0.4*(int(sqrt(x*x+z*z)/0.4)+0.5)*sin(Pa*int(acos(x/sqrt(x*x+z*z+0.000001))/Pa+1/2)),2)
      +pow(y-0.01* pow(int(sqrt(x*x+z*z)/0.4)+0.5,2),2)-pow(Rs,2))*(0.3+y-0.01*pow(x*x+z*z,1.2)/0.2
      -0.04*cos(10*pi*pow(x*x+z*z+pow(0.3+y,2),2)+pi))-0.0025
      }
    threshold 0
    max_gradient 20
    contained_by {box {<-5, -0.1, 0>, <5, 3, 5.6>}}
    texture {
      pigment {color rgb <1, 1, 1>}
      finish {
        ambient 0
        diffuse 0.8
        reflection 0.6
        specular 1
        phong 0.5
        brilliance 1
        }
      }
    no_shadow
    }

merge {
  object {Isounit}
  object {Isounit rotate y*180}
  }