// CASSINI / Exchanging coordinates - Swirling rotation '03.05
// By Tsutomu HIGO  E-mail: nj2t-hg@asahi-net.or.jp

#version 3.5;
global_settings {
  max_trace_level 4
  assumed_gamma 2.2
  }

camera {
  location <0, 30, -30>
  look_at <0, 0, 0>
  angle 7
  }

light_source {<-50, 150, -75> color rgb <0.8, 0.8, 0.8>}

isosurface {
  function {pow(pow(cos(0.4*pow(x*x+z*z,0.5))*x-sin(0.4*pow(x*x+z*z,0.5))*z,2)
    +4*pow(y,2) +pow(sin(0.4*pow(x*x+z*z,0.5))*x+cos(0.4*pow(x*x+z*z,0.5))*z,2),2)
    -0.996*4*pow(cos(0.4*pow(x*x+z*z,0.5))*x-sin(0.4*pow(x*x+z*z,0.5))*z,2)
    *pow(sin(0.4*pow(x*x+z*z,0.5))*x+cos(0.4*pow(x*x+z*z,0.5))*z,2)-pow(1,4)}
  threshold 1
  max_gradient 500
  contained_by {box {<-5, -0.8, -5>, <5, 0.8, 5>}}
  //open
  texture {
    pigment {color rgb <1, 1, 0.5>}
    finish {
      ambient 0.2
      diffuse 1
      reflection 0.5
      specular 1
      phong 0.5
      brilliance 1
      }
    }
  scale 1/vlength(1)
  rotate <0, 0, 0>
  no_shadow
  }

background {color rgb <0, 0.2, 0.7>}