// CASSINI / Modifying the equation '03.06
// By Tsutomu HIGO  E-mail: nj2t-hg@asahi-net.or.jp

#version 3.5;
global_settings {
  max_trace_level 4
  assumed_gamma 2.2
  }

camera {
  location <2, 50, -35>
  look_at <0, 3, 0>
  angle 15
  }

light_source {<-50, 150, -75> color rgb <0.8, 0.8, 0.8>}

union {
  #declare N = 0; #while (N < 8)
    #switch (N)
      #case(0) #declare Pr = 1; #break
      #case(1) #declare Pr = 0.999; #break
      #case(2) #declare Pr = 0.99; #break
      #case(3) #declare Pr = 0.95; #break
      #case(4) #declare Pr = 0.9; #break
      #case(5) #declare Pr = 0.7; #break
      #case(6) #declare Pr = 0.4; #break
      #case(7) #declare Pr = 0.0; #break
    #end
    isosurface {
      function {pow(x*x+y*y+z*z,2) -Pr*4*z*z*x*x-pow(1,4)}
      threshold 0
      max_gradient 1000
      contained_by {box {<-8, -1, -8>, <8, 1, 6>}}
      //open
      translate <5-1.5*N-0.2*N*N, 10-2.5*N, -3*N+0.6*N*N>
      no_shadow
      }
  #declare N = N+1; #end
  texture {
    pigment {color rgb <1, 1, 0.5>}
    finish {
      ambient 0.2
      diffuse 1
      reflection 0.5
      specular 1
      phong 0.5
      brilliance 1
      }
    }
  rotate y*30
  }

background {color rgb <0, 0.2, 0.7>}