// EAT / A Birth in A Core '03.02
// by Tsutomu HIGO  E-mail: nj2t-hg@asahi-net.or.jp

#version 3.5;
global_settings {
  max_trace_level 4
  assumed_gamma 2.2
  }

camera {
  location <3, 1, -10>
  angle 90
  look_at <0.2, 0.6, 0>
  }

#declare R1 = seed(7);

#declare Media = media {
  emission 0.05
  intervals 10
  samples 1, 10
  confidence 0.9999
  variance 1/100
  density {
    spherical
    turbulence 0.4
    color_map {
      [0.0 color rgbt <0, 0, 0, 1>]
      [0.3 color rgbt <1.5, 0.5, 0, 0.6>]
      [1.0 color rgb  <1, 1, 1>]
      }
    scale <1, 1, 5>
    }
  }

#declare R1 = seed(7);

#macro Meshsquare (Pmaxx, Pmaxy, Pmaxz, Rrand, Rsize)
  #declare Cp = array[Pmaxx][Pmaxy][Pmaxz][3]

  #declare Xp=0; #while (Xp<Pmaxx)
    #declare Yp=0; #while (Yp<Pmaxy)
      #declare Zp=0; #while (Zp<Pmaxz)
        #declare Cp[Xp][Yp][Zp][0] = Xp/Pmaxx-0.5;
        #declare Cp[Xp][Yp][Zp][1] = Yp/Pmaxx-0.5*Pmaxy/Pmaxx;
        #declare Cp[Xp][Yp][Zp][2] = Zp/Pmaxx-0.5*Pmaxz/Pmaxx;
      #declare Zp = Zp+1; #end
    #declare Yp = Yp+1; #end
  #declare Xp = Xp+1; #end

union {
  #declare Xp=0; #while (Xp < Pmaxx)
    #declare Yp=0; #while (Yp < Pmaxy)
      #declare Zp=0; #while (Zp < Pmaxz)
        #if (pow(Cp[Xp][Yp][Zp][0], 2)+pow(Cp[Xp][Yp][Zp][1], 2)+pow(Cp[Xp][Yp][Zp][2], 2) < 0.25)
          #if (pow(Cp[Xp][Yp][Zp][0], 2)+pow(Cp[Xp][Yp][Zp][1], 2)+pow(Cp[Xp][Yp][Zp][2], 2) > 0.2)
            #if (Cp[Xp][Yp][Zp][1]+0.05*sin(15*Cp[Xp][Yp][Zp][2]+12*Cp[Xp][Yp][Zp][0]+0.1) > 0.1*rand(R1))
              sphere {<Cp[Xp][Yp][Zp][0], Cp[Xp][Yp][Zp][1]/1.5, Cp[Xp][Yp][Zp][2]> Rsize/Pmaxx*2 rotate z*30} 
            #else 
              sphere {<Cp[Xp][Yp][Zp][0]-0.02, Cp[Xp][Yp][Zp][1]/1.5-0.1, Cp[Xp][Yp][Zp][2]+0.03> Rsize/Pmaxx*2 rotate <-5, -15, 27>} 
            #end
          #else
            #if (0.97 < rand(R1))
              sphere {<Cp[Xp][Yp][Zp][0]/(rand(R1)+0.00001)-0.01, Cp[Xp][Yp][Zp][1]-0.1, Cp[Xp][Yp][Zp][2]/(rand(R1)+0.00001)+0.015> Rsize/Pmaxx*2 rotate <-2.5, -7.5, 25>} 
            #end
          #end
        #end
      #declare Zp = Zp+1; #end
    #declare Yp = Yp+1; #end
  #declare Xp = Xp+1; #end
  pigment {color rgb <0.7, 0.8, 1>}
  finish {
    reflection 1
    phong 1
    brilliance 2
    ambient 0.1
    }
  no_shadow
  translate <0.5/Pmaxx, 0.5/Pmaxx, 0>
  scale 10
  }

#end

union {
  object {Meshsquare (60, 60, 60, 0.8, 0.25)}
  sphere {0, 100
    scale <5, 1, 5>
    pigment {color rgbf <1, 1, 1, 1>}
    finish {ambient 1 diffuse 0}
    interior {media {Media}}
    hollow
    scale 5
    rotate <-2.5, 7.5, 25>
    }
  }