// EAT / Edges Being Bited '03.02
// by Tsutomu HIGO  E-mail: nj2t-hg@asahi-net.or.jp

#version 3.5;
global_settings {
  max_trace_level 4
  assumed_gamma 2.2
  }

camera {
  location <8, 0, -15>
  angle 70
  look_at <0.4, -1.0, 0>
  }

#declare R1 = seed(7);

#declare Media = media {
  emission 0.05
  intervals 30
  samples 1, 10
  confidence 0.9999
  variance 1/100
  density {
    spherical
    turbulence 0.4
    color_map {
      [0.0 color rgbt <0, 0, 0, 1>]
      [0.3 color rgbt <0, 0, 0.8, 0.6>]
      [1.0 color rgb  <1.5, 1.5, 1.5>]
      }
    scale 4
    }
  }

#declare R1 = seed(7);

#macro Meshsquare (Pmaxx, Pmaxy, Pmaxz, Rrand, Rsize)
  #declare Cp = array[Pmaxx][Pmaxy][Pmaxz][3]

  #declare Xp = 0; #while (Xp < Pmaxx)
    #declare Yp = 0; #while (Yp < Pmaxy)
      #declare Zp=0; #while (Zp < Pmaxz)
        #declare Cp[Xp][Yp][Zp][0] = Xp/Pmaxx+0.3;
        #declare Cp[Xp][Yp][Zp][1] = Yp/Pmaxx-0.5*Pmaxy/Pmaxx;
        #declare Cp[Xp][Yp][Zp][2] = Zp/Pmaxx;
      #declare Zp =Zp+1; #end
    #declare Yp = Yp+1; #end
  #declare Xp = Xp+1; #end

  union {
    #declare Xp = 0; #while (Xp < Pmaxx)
      #declare Yp = 0; #while (Yp < Pmaxy)
        #declare Zp = 0; #while (Zp < Pmaxz)
          #if (pow(Cp[Xp][Yp][Zp][0], 2)/2+pow(Cp[Xp][Yp][Zp][1], 2)+pow(Cp[Xp][Yp][Zp][2], 2) > 0.8-0.6*rand(R1))
            sphere {<Cp[Xp][Yp][Zp][0], Cp[Xp][Yp][Zp][1], Cp[Xp][Yp][Zp][2]> Rsize/Pmaxx*2}
          #else  sphere {<Cp[Xp][Yp][Zp][0], Cp[Xp][Yp][Zp][1], Cp[Xp][Yp][Zp][2]> Rsize/Pmaxx*2 rotate <-20, 20, 40> translate <-1.0, -0.6, -0.14>}
          #end
        #declare Zp = Zp+1; #end
      #declare Yp = Yp+1; #end
    #declare Xp = Xp+1; #end
    pigment {color rgb <1.0, 1.0, 1.0>}
    finish {
      reflection 1
      phong 1
      ambient 0.1
      }
    no_shadow
    scale 10
    }

#end

union {
  object {Meshsquare (20, 50, 25, 0.8, 0.25)}
  sphere {0, 100
    pigment {color rgbf <1, 1, 1, 1>}
    finish {ambient 1 diffuse 0}
    interior {media {Media}}
    hollow
    scale 4
    }
  rotate z*30
  }