// RONDO / Rondo06 '02.09
// By Tsutomu HIGO  E-mail: nj2t-hg@asahi-net.or.jp

#version 3.5;
global_settings {
  max_trace_level 3
  assumed_gamma 2.2
  }

#include "functions.inc"

union{
  #declare I=-16; #while (I<42)
    isosurface {
      function {
        (z-0.7*sin(1.5*pow(y,0.6)))*(z-0.7*sin(1.5*pow(y,0.6)))
        +(x-0.2*sin(3*pow(y,0.6)))*(x-0.2*sin(3*pow(y,0.6)))
        -0.05*sin(2*pi*y/15)+0.0012*I
        }
      threshold 0
      contained_by {
        box {<-0.4+0.004*I, 0+0.0001*(I+16)*(I+16), -1.2>, <0.4-0.004*I, 9-0.05*I, 1.2>}         }
      max_gradient 3
      rotate x*-40
      translate y*(3-0.03*I)
      rotate <0,0,I*10>
      translate z*-0.15*I
      }
  #declare I=I+1; #end
  texture {
    pigment {color rgb <0.9,0.95,1>}
    finish {
      ambient 0.35
      diffuse 0.7
      reflection 0
      brilliance 0.7
      }
    }
  rotate z*45
  rotate x*60
  no_shadow
  }

camera {
  location <0, 0, -30>
  angle 38
  look_at <1, 3.4, 0>
  }

light_source {<500, 500, -1500> color rgb 1}

background { color rgb <0.05, 0.1, 0.2> }